

********************************
***************Generates Tables A.1-A.3
********************************

 cd C:\Users\mjaremski\Desktop\ReplicationFile\Data\

******Count each bank's number of respondents
 use "NYBS+.dta", clear
 keep if yr==1915
 preserve
 forvalues i=1/8 {
	keep bankNYCorr`i' locationNYCorr`i'
	rename bankNYCorr`i' bank
	rename locationNYCorr`i' location 
	save temp`i', replace
	restore
	preserve
	}
 restore 
 clear
 use temp1.dta, clear
 forvalues i=2/8 {
	append using temp`i'.dta
	}
  gen corr=1
 drop if bank==""
 collapse (sum) corr, by(bank location)
 save corr.dta, replace

******Obtain city-level population number for min capital calculation
 insheet using "NYCities.csv", clear
 drop county
 save temp.dta, replace


******Generate Variables for Regressions
 use "NYBS+.dta", clear

 joinby using corr.dta, unmatched(master)
 drop _merge

 replace corr=0 if corr==.
 bysort bankid: egen endyr=max(yr)

 gen deflator=deflate/12.85

 gen pop=ln(totpop1920)
 gen mout=ln(mfgout1920/(deflator*totpop1920))
 gen fout=ln(farmout1920/(deflator*totpop1920))
 gen cerealout=ln(cerealva1920/(deflator*totpop1920))
 gen Illit=Illit1920
 gen urban=urb1920/totpop1920
 gen fruittrees=ln(ftrees1920+1)
 gen cacres=ln(cerealac1920+1)

 drop if beginyr>1913
 drop if endyr<1921

 drop if deposits==0 | loans==0 | cash==0
 drop if corresp==0
 drop if assets1914==.

 bysort bankid: egen startyr=min(yr)

 xtset bankid yr

 replace fedmemb=1 if fedmemb==0 & F.fedmemb==1
 drop if L.fedmemb==1

 replace nonnycorresp=nonnycorresp+foreigncorresp
 gen nyshare=nyccorr/corresp

 gen relvalue=assets/(fedmembassetsnearby)
 drop if yr>1920

 rename disttoFedmemb dist

 rename Loan_Swing_34_percent1914 loanswing1914

 gen distResCity=distNY

 replace assets1914=ln(assets1914+1)
 replace fedmembassetsnearby=ln(fedmembassetsnearby+1)

 gen corrdum=0
 replace corrdum=1 if corr>0

 replace location=upper(location)

 joinby state stateicp countycode location using temp.dta, unmatched(master)
 drop _merge
 
 egen mincapital=min(capital), by(bankid)
 replace mincap=25000 if mincap==.

 gen nomincap=0
 replace nomincap=1 if mincapital>=mincap


*************Generate Table A.1
 preserve
 keep if yr==1915

 gen temp=1
 bysort countycode: egen totalmembever=max(fedmembever)
 bysort countycode: egen totalcountyobs=total(temp)

 drop if totalmembever==0 | totalcountyobs==1

 xi: logit fedmembever distResCity fedmembassetsnearby relvalue corresp nyshare corrdum pop urban Illit fout cacres fruittrees mout , robust
 estimates store t1

 xi: logit fedmembever trust chmemb distResCity fedmembassetsnearby relvalue corresp nyshare corrdum pop urban Illit fout cacres fruittrees mout , robust
 estimates store t2

 xi: logit fedmembever nomincap trust chmemb distResCity fedmembassetsnearby relvalue corresp nyshare corrdum assets1914 loas1914 loanswing1914 pop urban Illit fout cacres fruittrees mout , robust
 estimates store t3

 esttab t1 t2 t3 using TableA1.csv, replace b(3) se(3) margin pr2 starlevels(* 0.10 ** 0.05 *** 0.01) brackets label title("Table A.1") wrap order(trust chmemb distResCity fedmembassetsnearby relvalue corresp nyshare corrdum assets1914 nomincap loas1914 loanswing1914 pop urban Illit fout cacres fruittrees mout)

*************Generate Table A2
 restore
 preserve

 gen dob=1914
 stset yr, failure(fedmemb==1) origin(dob) id(bankid) 

 gen temp=1
 bysort countycode: egen totalmembever=max(fedmembever)
 bysort countycode: egen totalcountyobs=total(temp)

 drop if totalmembever==0 | totalcountyobs==1

 xi: streg distResCity fedmembassetsnearby relvalue corresp nyshare corrdum i.countycode, distribution(loglogistic) robust
 estimates store z1

 xi: streg trust chmemb distResCity fedmembassetsnearby relvalue corresp nyshare corrdum i.countycode, distribution(loglogistic) robust
 estimates store z2

 xi: streg trust nomincap chmemb distResCity fedmembassetsnearby relvalue corresp nyshare corrdum assets1914 loas1914 loanswing1914 i.countycode, distribution(loglogistic) robust
 estimates store z3

 esttab z1 z2 z3 using TableA2.csv, replace b(3) se(3) margin pr2 starlevels(* 0.10 ** 0.05 *** 0.01) brackets label title("Table A.2") wrap order(trust chmemb distResCity fedmembassetsnearby relvalue corresp nyshare corrdum assets1914 nomincap loas1914 loanswing1914)


*************Generate Table A.3
 restore
 preserve

 keep if yr==1915

 gen temp=1
 bysort countycode: egen totalmembever=max(fedmembever)
 bysort countycode: egen totalcountyobs=total(temp)

 drop if location=="NEW YORK"
 drop if totalmembever==0 | totalcountyobs==1

 xi: logit fedmembever trust chmemb distResCity fedmembassetsnearby relvalue corresp nyshare corrdum i.countycode, robust
 estimates store m1

 xi: logit fedmembever trust chmemb distResCity fedmembassetsnearby relvalue corresp nyshare corrdum assets1914 loas1914 loanswing1914 i.countycode, robust
 estimates store m2

 restore
 
 keep if corr==0
 keep if yr==1915

 gen temp=1
 bysort countycode: egen totalmembever=max(fedmembever)
 bysort countycode: egen totalcountyobs=total(temp)
 drop if totalmembever==0 | totalcountyobs==1

 xi: logit fedmembever trust chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.countycode, robust
 estimates store m3

 xi: logit fedmembever nomincap trust chmemb distResCity fedmembassetsnearby relvalue corresp nyshare assets1914 loas1914 loanswing1914 i.countycode, robust
 estimates store m4

 esttab m1 m2 m3 m4 using TableA3.csv, replace b(3) se(3) margin pr2 starlevels(* 0.10 ** 0.05 *** 0.01) brackets label title("Table A.3") wrap order(trust chmemb distResCity fedmembassetsnearby relvalue corresp nyshare corrdum assets1914 nomincap loas1914 loanswing1914)

